※タイトル見て「akrantiainってなんぞや」と思った奴方はこのこちらのページを見てくれよな！ご覧ください。
皆様お久しぶりです。さざんかです。
……といっても、今回は言語の深掘りとか、あるいは文化的背景についての解説とかではありません。はい。私が「記事書けた！ 進捗あります！」と安心するためのなんちゃって進捗記事です。
最近は、言語含めその他創作色々が停滞気味だったりするという創作者にあるまじき日々を送っているのですが。「そういえばデナスティア語のakrantiainが読みにくくなってたから直そう」と一念発起(？)しまして。
約1時間弱かけて直しました。……疲れたりはしませんでしたが。
エラーメッセージが出たのですが、そこを直しても直らず。そして探してみれば「"」が不要なのについていたというミスが全然別の場所で発生していました……。これでもゼロから始めた前回に比べたらまだマシだったりするという始末。
ちなみにakrantiainが読みにくくなった戦犯はアポストロフィです(アポストロフィを後から入れたのは作者なので本当の戦犯は作者のさざんかです。はい)。
もちろん、不具合が全くないわけではないと思う(あんまりテストしてない)ので、見つけ次第直していく予定です。
見た目はかなり汚いですが、これでもマシになったのですよ……！
(つまり直す前はもっと汚かったわけですが。どのくらい汚かったかは察してください)
(migdalの記事の数倍カオスになっていました……)
(間違い探しをしてみてもいいかもしれません？)
#グループ#
PUNCTION = "." | "," | "!" | "?" | "-";
tcj = "tcj" | "tcj'"; cj = "cj" | "cj'"; tz = "tz" | "tz'";
a = "a" | "a'"; b = "b" | "b'"; c = "c" | "c'"; d = "d" | "d'";
e = "e" | "e'"; f = "f" | "f'"; g = "g" | "g'"; h = "h" | "h'";
i = "i" | "i'"; j = "j" | "j'"; k = "k" | "k'"; l = "l" | "l'";
m = "m" | "m'"; n = "n" | "n'"; o = "o" | "o'"; p = "p" | "p'";
r = "r" | "r'"; s = "s" | "s'"; t = "t" | "t'"; u = "u" | "u'";
v = "v" | "v'";
vow = a o | a | e | i | o | u;
con = b | c | d | f | g | k | m | n | p | r | s | t | cj | tz | tcj;
stop = b | d | g | k | m | n | p | r vow | t | tz | tcj;
vpls = b | d | g;
sem = j | v;
sf = s | f | cj;
dvow = a i | a u | a o | e a | e i | e u | e o | i a | i u | i e | i o | u a | u i | u e | u o | o i | o u | a a | i i | u u | e e | o o;
vowj = vow | j;
tzaleh = a | b | c | cj | d | e | f | g | h | i | j | k | l | m | n | o | p | r | s | t | tcj | tz | u | v;
#原形不定詞を除き、ae、oeは禁則#
#その他にも禁則あり#
#文中規則#
"n" ( ^ | "-" ) ( "m" | "p" | "b" ) -> /m/ $ $;
"n" ( ^ | "-" ) ( "n" | "t" | "d" ) -> /n/ $ $;
"n" ( ^ | "-" ) ( "k" | "g" ) -> /ŋ/ $ $;
"n" ( ^ | "-" ) "c" !"j" -> /ŋ/ $ $;
"n" ( ^ | "-" ) ( "u" vow | "v" ) -> /ɱ/ $ $;
"n" ( ^ | "-" ) vowj -> /ɴn/ $ $;
"n" ( ^ | "-" ) ( "r" vow | "tcj" ) -> /ɳ/ $ $;
n "e" ( ^ | "-" ) "u" vow -> /n/ // $ $ $;
n "e" ( ^ | "-" ) vowj -> /nn/ // $ $;
!( ^ | vow | "j" | "l" | "v" ) ( "e" | "e'" ) "n" ( ^ | "-" ) vowj -> /ə/ /nn/ $ $;
( "n" | "n'" ) "r" ( ^ | "-" ) vowj -> /ɳ/ /ʈ/ $ $;
"r" ( ^ | "-" ) vowj -> /ʈ/ $ $;
"m" ( ^ | "-" ) ( "u" vow | "v" ) -> /ɱ/ $ $;
( "t" | "r" ) ( ^ | "-" ) "r" vow -> /ʈ/ $ $ $;
( "t" | "r" ) ( ^ | "-" ) "tcj" -> /ʈ/ $ $;
"b" ( ^ | "-" ) vowj -> /b/ $ $;
"d" ( ^ | "-" ) vowj -> /d/ $ $;
"g" ( ^ | "-" ) vowj -> /g/ $ $;
( "v" | "v'" ) "e" ( ^ | "-" ) vowj -> /ʋ/ // $ $;
e ( ^ | "-" ) !^ -> /e/ $;
#文中特殊発音規則#
^ "e-" ^ -> /e/;
^ "al" ^ con -> /ao/ $;
( "a" | "o" | "ae" | "oe" ) ^ "es" ^ -> $ /jes/;
^ "ua" ^ vowj -> /wal/ $;
#語中規則#
( dvow | j vow | vow h ) v e ^ -> $ /ɸ/ //;
v e ^ -> /ʋ/ //;
( dvow | vow h ) v ( con | l ) -> $ /ʋ/ $
^ u vow -> /w/ $;
!c j u vow -> /j/ /ʉ/ $;
u a -> /w/ $;
u o -> /ʊ/ /o/;
u e !^ -> /ʉ/ $;
u i !^ -> /ɨ/ $;
i j i h -> /i/ // // $;
i j i i -> // // $ $;
i j i l con -> /i/ // // $ $;
i j i !i -> /i/ // /:/;
( ^ | "-" ) ( con | j | l | v ) e ( ^ | "-" ) -> $ $ /ə/ $;
h e ^ -> // /e/;
!vpls "e" ( ^ | "-" ) -> // $;
vpls e ( ^ | "-" ) -> $ /ə/ $;
e i ^ -> /e/ //;
e i j ^ -> /e/ // /j/;
( a | o | u ) i j ^ -> $ $ //;
j ( e | i ) u -> /j/ // /u:/;
( con | l | sem ) ( i | e ) v ( con | "l" | ^ ) -> $ /ɪ/ /u/ $;
( con | l | sem ) a v ( con | "l" | ^) -> $ /o/ /:/ $;
( con | l | sem ) ( o | u ) v ( con | "l" | ^ ) -> $ /u/ /:/ $;
^ ( con | con vow | con l | con j | con "v" ) e n ^ -> $ /e/ /ɴ/;
!( ^ | vow | j | l | v ) e n ^ -> /ə/ /ɴ/;
a u -> /o/ /:/;
o u -> /u/ /:/;
( e | i ) u -> /ɪ/ /u/;
o a -> // /a/;
( a | o | u ) i ^ -> $ /j/;
i j ^ -> /i/ //;
( ^ j | ^ i ) e -> $ /ɛ/;
!c j i -> // /i/;
a a -> /a/ /:/;
i i -> /i/ /:/;
u u -> /u/ /:/;
e e -> /e/ /:/;
o o -> /o/ /:/;
vow h ( con | "l" | "j" | "v" ) -> $ /:/ $;
vow vow l "h" ^ -> $ $ /l/ //;
vow l h ^ -> $ // /:/;
vow l h vow -> $ // /:/ $;
l l -> /l/ //;
vow h -> $ //;
( con | dvow ) l con -> $ // $;
vow l ( con | "v" | "j" ) -> $ /:/ $;
( p | b ) ( p | b )-> // $;
c ( c | k | g ) -> // $;
( t | d ) ( t | d ) -> // $;
f f -> // $;
( k | g ) ( k | g ) -> // $;
j j -> // $;
r r ( ^ | con ) -> // $ $;
s s -> // $;
( k | g ) c !"j" -> // $;
r vow -> /ʈ/ $;
!^ n v -> /ɱ/ $;
^ m u a -> /m/ $ $;
m ( u a | f | v ) -> /ɱ/ $;
n ( sf | ^ ) -> /ɴ/ $;
n ( r vow | tcj ) -> /ɳ/ $;
n ( k | g | c ) -> /ŋ/ $;
tcj -> /ʈ͡ʂ/;
cj -> /ʂ/;
tz -> /t͡s/;
c !"j" -> /k/;
g c !j -> /ɣ/ $;
d c !j -> /d/ $;
b c !j -> /b/ $;
g stop -> /ɣ/ $;
d stop -> /d/ $;
b stop -> /b/ $;
b ( h ^ | ^ ) -> /p/ $;
d ( h ^ | ^ ) -> /t/ $;
g ( h ^ | ^ ) -> /k/ $;
#その他#
a -> /a/;
i -> /i/;
o -> /o/;
u -> /u/;
e -> /e/;
p h -> /ɸ/ //;
p f -> /ɸ/ //;
p -> /p/; b -> /b/;
t -> /t/; d -> /d/;
k -> /k/; g -> /g/;
f -> /ɸ/; s -> /s/;
m -> /m/; n -> /n/;
j -> /j/; v -> /ʋ/;
r -> /l/; l -> /l/;
h -> //;
"'" -> //;
"-" -> //;
"," -> //;
"." -> //;
"!" -> //;
"?" -> //;
(追記。辞書の登録単語数が1600になったのでこんな記事書かなくても進捗はきちんとありました……やっぱり私はぽんこつです)
Top comments (1)
あとで差分取る（多分忘れる）